#!/usr/bin/perl

##############################################################################
# twittersleep - cache twitter tweets while AFK
# v0.01
# Copyright (c) 2007 Jay Savage
##############################################################################

use strict;
use warnings;
use LWP::UserAgent;
use XML::Simple;

### CONFIG:
my %t_info = (
    user     => q/XXXXXXXXX/,                                        # Your twitter user name
    email    => q/XXXXXXXXX@XXXXX.XXX/,                              # The email on record with twitter
    pass     => q/********/,                                         # your twitter password
    apihost  => 'twitter.com:80',
    apirealm => 'Twitter API',
    apilink  => 'http://twitter.com/statuses/friends_timeline.xml'
);

my $dbfile = "twitsleep";

### END CONFIG ###

if ( @ARGV && ( $ARGV[0] =~ /r/ ) ) {
    read_tweets();
} else {
    file_tweets();
}

sub file_tweets {
    if ( -e $dbfile ) {
        unlink($dbfile) or die "couldn't remove old tweet file $dbfile: $!\n";
    }
    dbmopen( my %TWEETDB, $dbfile, 0666 ) or die "Can't initialize tweet database $dbfile: $!\n";

    my $ua = LWP::UserAgent->new();
    $ua->credentials( @t_info{qw/apihost apirealm email pass/} );

    while (1) {
        sleep 300;
        dbmopen( my %TWEETDB, $dbfile, 0666 ) or die "Can't initialize tweet database $dbfile: $!\n";
        my $res;
        eval { $res = $ua->get( $t_info{apilink} ) };
        if ($@) {
            warn "Fetch failed: $@\n";
            next;
        }
        my $tweets;
        eval { $tweets = XMLin( $res->content() ) };
        if ($@) {
            warn "Fetch failed: $@\n";
            next;
        }
        foreach ( keys %{ $tweets->{status} } ) {
            $TWEETDB{$_} = join '%%%$$$%%%', $tweets->{status}->{$_}->{created_at},
              $tweets->{status}->{$_}->{user}->{screen_name}, $tweets->{status}->{$_}->{text};
        }
    } ## end while (1)
} ## end sub file_tweets

sub read_tweets {
    dbmopen( my %TWEETDB, $dbfile, 0666 ) or die "Can't initialize tweet database $dbfile: $!\n";
    foreach ( sort { $a <=> $b } keys %TWEETDB ) {
        print "$_\n";
        my @tweet = split '%\%\%\$\$\$\%\%\%', $TWEETDB{$_};
        print $tweet[1], ' @ ', $tweet[0], "\n";
        print $tweet[2], "\n\n";
    } ## end foreach ( sort { $a <=> $b ...
} ## end sub read_tweets

__END__

=head1 NAME

twittersleep - cache twitter tweets while AFK

=head1 VERSION

This document describes twittersleep version 0.01

=head1 SYNOPSIS

twittersleep

twittersleep -r 

=head1 DEPENDENCIES

=over

=item L<LWP::UserAgent>

=item L<XML::Simple>

=back

=head1 AUTHOR

Jay Savage <perl@engatiki.org>

    
=head1 LICENCE AND COPYRIGHT

Copyright (c) 2007, Jay Svage <perl@engatiki.org>. All rights
reserved.

This module is free software; you can redistribute it and/or
modify it under the same terms as Perl itself. See L<perlartistic>.


=head1 DISCLAIMER OF WARRANTY

BECAUSE THIS SOFTWARE IS LICENSED FREE OF CHARGE, THERE IS NO WARRANTY
FOR THE SOFTWARE, TO THE EXTENT PERMITTED BY APPLICABLE LAW. EXCEPT WHEN
OTHERWISE STATED IN WRITING THE COPYRIGHT HOLDERS AND/OR OTHER PARTIES
PROVIDE THE SOFTWARE "AS IS" WITHOUT WARRANTY OF ANY KIND, EITHER
EXPRESSED OR IMPLIED, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED
WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE. THE
ENTIRE RISK AS TO THE QUALITY AND PERFORMANCE OF THE SOFTWARE IS WITH
YOU. SHOULD THE SOFTWARE PROVE DEFECTIVE, YOU ASSUME THE COST OF ALL
NECESSARY SERVICING, REPAIR, OR CORRECTION.

IN NO EVENT UNLESS REQUIRED BY APPLICABLE LAW OR AGREED TO IN WRITING
WILL ANY COPYRIGHT HOLDER, OR ANY OTHER PARTY WHO MAY MODIFY AND/OR
REDISTRIBUTE THE SOFTWARE AS PERMITTED BY THE ABOVE LICENCE, BE
LIABLE TO YOU FOR DAMAGES, INCLUDING ANY GENERAL, SPECIAL, INCIDENTAL,
OR CONSEQUENTIAL DAMAGES ARISING OUT OF THE USE OR INABILITY TO USE
THE SOFTWARE (INCLUDING BUT NOT LIMITED TO LOSS OF DATA OR DATA BEING
RENDERED INACCURATE OR LOSSES SUSTAINED BY YOU OR THIRD PARTIES OR A
FAILURE OF THE SOFTWARE TO OPERATE WITH ANY OTHER SOFTWARE), EVEN IF
SUCH HOLDER OR OTHER PARTY HAS BEEN ADVISED OF THE POSSIBILITY OF
SUCH DAMAGES.